现在我们将Flash加载外部文件的各种方法与技巧总结如下。
一、用loadVariables调用外部文本文件
文本文件开头要以flash中的动态文本框的变量名开头，如msg="………."这样的形式，要和编辑的Flash文件放在同一目录下。
具体调用方式如下：
1.用工具箱中的文本工具，选择动态文本，给动态文本一个变量名，如:msg,在编辑区拖出一个文本框
2.制作两个按扭（一个调用，一个清除）拖放到场景中。
3.在调用按扭上添加AS代码：
on(release){//松开鼠标后执行下面的代码；
loadVariables("msg.txt",msg);//调用和你编辑的Flash处于同一目录下的msg.txt文本文件到动态文本msg中；
System.useCodepage=true;//使外部文件的中文字符能够正确显示；
}
4.清除按扭上的AS代码：
on(release){//松开鼠标后清楚动态文本框中的内容；
msg="";
}
Ctrl+Enter测试.
当然代码也可以写在帧上:(调用按扭的实例名是bt1,清除按扭的实例名是bt2)
第一帧上加如下代码：
stop();
_root.bt1.onRelease=function(){
loadVariables("msg.txt",msg);
System.useCodepage=true;
}
_root.bt2.onRelease=function(){
_root.msg="";
}
Ctrl+Enter测试.
进阶：让调用的外部文本文件能够滚动
1.用工具箱中的文本工具，选择动态文本，给动态文本一个变量名，如:msg,在编辑区拖出一个文本框
2.新建一层,制作两个按扭（一个调用，一个清除）拖放到此层中
3.新建一层,在动态文本框的右侧用矩形工具画一个竖条,高度和动态文本一样;再制作一个向上的方向"箭头"按F8转为按扭元件;复制一个"箭头"按扭,垂直镜象,使这两个按扭和竖条的两端对齐.
4.调用按扭上的AS代码：
on(release){//松开鼠标后执行下面的代码；
loadVariables("msg1.txt",msg);//调用msg1.txt文本文件到动态文本框msg中；
System.useCodepage=true;//使外部文件的中文字符能够正确显示；
}
清除按扭上的AS代码：
on(release){
_root.msg="";//清除动态文本框中的内容;
}
向上按扭上的AS代码：
on(press){//在按扭的感应区上每按一次鼠标执行下面的代码;
_root.msg.scroll=_root.msg.scroll-1;//文本向下滚动一行;
}
向下按扭上的AS代码：
on(press){//在按扭的感应区上每按一次鼠标执行下面的代码;
_root.msg.scroll=_root.msg.scroll+1;//文本向上滚动一行;
}
Ctrl+Enter测试.
当然代码也可以写在帧上:(调用按扭的实例名是bt1,清除按扭的实例名是bt2,向上按扭的实例名是:up,向下按扭上的实例名是down)
在第一帧上加如下代码：
_root.bt1.onRelease=function(){//松开鼠标后执行下面的代码；
loadVariables("msg1.txt",msg);//调用msg1.txt文本文件到动态文本框msg中；
System.useCodepage=true;//使外部文件的中文字符能够正确显示；
}
_root.bt2.onRelease=function(){//松开鼠标后执行
_root.msg="";//清除动态文本框中的内容;
}
_root.up.onPress=function(){//在向上按扭上每按一次鼠标执行下面的代码;
_root.msg.scroll=_root.msg.scroll-1;//文本向下滚动一行;
}
_root.down.onPress=function(){//在向下按扭上每按一次鼠标执行下面的代码;
_root.msg.scroll=_root.msg.scroll+1;//文本向上滚动一行;
}
Ctrl+Enter测试。
二、用loadMovie调用外部*.swf文件
（一）调用外部*.swf文件加载到影片剪辑中
外部*.swf文件要和编辑的Flash文件放在同一目录下
1.新建立一个空的影片剪辑mymc,把它放在场景中，实例名是：mymc.
2.新建一层,制作两个按扭（一个调用，一个清除）拖放到此层中
3.调用按扭上的AS代码：
on(release){//鼠标离开按扭后执行下面的代码；
loadMovie("flash8.swf","mymc");//加载外部的"flash8.swf"文件到"mymc"空影片剪辑中；
mymc._x=70;//加载影片的X轴坐标；
mymc._y=20;//加载影片的Y轴坐标；
mymc._xscale=70;//加载影片的宽度；
mymc._yscale=70;//加载影片的高度；
}
清除按扭上的AS代码：
on(release){//鼠标离开按扭后执行下面的代码
unloadMovie(mymc);//删除用loadMovie加载的*.swf文件；
}
Ctrl+Enter测试
（二）调用外部*.swf文件并加载到时间轴上
外部*.swf文件要和编辑的Flash文件放在同一目录下
1.制作两个按扭（一个调用，一个清除）拖放到场景中
2.调用按扭上的AS代码：
on(release){//鼠标离开按扭后执行下面的代码
loadMovie("flash8.swf",1);//加载外部的"flash8.swf"文件到场景中，层深为1;
}
清除按扭上的AS代码：
on(release){//鼠标离开按扭后执行下面的代码
unloadMovie(1);//删除层深为1的用loadMovie所加载的"flash8.swf"文件
}
Ctrl+Enter测试 。
当然二和三的代码都可以写在帧上。
三、用loadMovie调用外部图片，加载到影片剪辑中
将外部图片必须和正在编辑的Flash文件放在同一目录下
1.制作两个按扭（一个调用，一个清除）拖放到场景中
2.制作一个空的影片剪辑，拖到场景中，实例名是：mymc;
3.时间轴上第一帧上的AS如下： i=0;//定义一个变量i，并且赋初值为0；
调用按扭上的AS代码：
on(release){//鼠标离开按扭后执行下面的代码；
i++;
if(i>9){//因为外面这有9张图，当变量大于9的时候，让变量为1，这样能够使加载的图片是连续的，即，每点一次按扭，就换一张图，等到换到第9张图，再点按扭，则循环到第一张图（j1.jpg到j9.jpg,因为没有j0.jpg,如果i=0，则会提示没有找到j0.jpg);
i=1;
}
loadMovie(("j"+i)+".jgp",mymc);//从j1.jpg开始加载图片到影片剪辑mymc中；
mymc._x=110;//以下设置加载图片的属性
mymc._y=35;
mymc._xscale=130;
mymc._yscale=130;
}
清除按扭上的AS代码：
on(release){
unloadMovie(mymc);//删除掉用loadMovie加载到影片剪辑的图片；
}
Ctrl+Enter测试。当然AS代码也可以写在帧上。
四、用mySound.loadSound调用外部声音文件，加载到场景中
外部声音文件必须和正在编辑的Flash文件放在同一目录下
1.制作两个按扭（一个调用，一个清除）拖放到场景中
2.调用按扭上的AS代码：
on(release){//鼠标离开按扭后执行下面的代码；
mySound=new Sound();//建立一个新的声音对象mySound;
mySound.loadSound("zaihuni.mp3″,true);//加载外部的*.mp3声音文件到mySound对象中，并且按流的方式播放（参数为false时，是以装载完后播放)；
}
清除按扭上的AS代码：
on(release){
mySound.stop();//当按下清除按扭后，停止声音的播放
}
Ctrl+Enter测试。
五、用loadMovieNum()函数调用所有外部文件
（一）loadMovieNum()函数详解
用法：loadMovieNum("url",level [, variables])
功能：在播放原来加载的 SWF 文件的同时将 SWF 文件或 JPEG 文件加载到 Flash Player 中的某个级别。
参数：该函数有3个参数：url、target、variables。variables 是可选参数。
1.参数url：要加载的 SWF 文件或 JPEG 文件的绝对或相对 URL（路径）。该函数的此参数和上面loadMovie中的此参数用法完全一致，这里不再作解释。
2.参数level：一个整数，指定 SWF 文件将加载到Flash Player中的哪个级别。加载的时候，可以这样来写：
loadMovieNum("01.swf", 1);
loadMovieNum("02.swf", 2);
loadMovieNum("03.swf", 3);
loadMovieNum加载后的控制可以这样使用： _level1._x=10 ;
_level2.aa._alpha=50 ;
_level3.aa.bb._width=110;
_level4.mysound.stop();// 加载到级别为4的对象MC:mysound停止（播放音乐）
需要注意的的是，每一个级别只能同时存在一个 SWF 或 JPEG 文件。如果两个 SWF 或 JPEG 文件的级别相同，那么后者将替换掉前者。级别不同的_level，级别大的将覆盖掉级别小的，即：数字大的将处于数字小的之上(如上例：03.swf处在02.swf和01.swf上方，02.swf处在01.swf上方) 。
注意：如果将 SWF 文件加载到级别 0，则 Flash Player 中的每个级别均被卸载，并且级别 0 将替换为该新文件。处于级别 0 的 SWF 文件为所有其它加载的 SWF 文件设置帧频、背景色和帧大小。如：
loadMovieNum("00.swf", 0); //以下均不显示，这样只有一个00.swf
loadMovieNum("01.swf", 1);
loadMovieNum("02.swf", 2);
3.参数variables：可选参数，指定发送变量所使用的 HTTP 方法。该参数必须是字符串 GET 或 POST。如果没有要发送的变量，则省略此参数。GET 方法将变量追加到 URL 的末尾，它用于发送少量的变量。POST 方法在单独的 HTTP 标头中发送变量，它用于发送大量的变量。
（二）loadMovieNum()的卸载外部文件调用
使用 unloadMovieNum() 可删除用 loadMovieNum() 加载的 SWF 文件或图像。
用法: unloadMovieNum(level)
参数: level 所加载影片的级别 (_levelN)。
如： on(release){
unloadMovieNum (1200);//如下:unloadMovieNum (_level1200);不能卸载
loadMovieNum ("sje.swf",1200)
}
（三）lloadMovieNum()的定位
从前面我们已经知道了，函数loadMovieNum是将 SWF 或 JPEG 文件加载到_level（级别）的。并且是用_level1._x、_level2._x、_level1.aa._x之类的来定位的。比如我们要将02.swf加载到主场景坐标系的(50,100)中，代码如下：
loadMovieNum ( “02.swf" , 1 ); //极有可能不能如愿定位
_level1. _x = 50 ;
_level1. _y = 100 ;
但是在测试的时候大家会发现加载进来的02.swf并没有如我们预期的那样出现在主场景坐标系的(50,100)位置，这是为什么呢？
原来，在没有使用loadMovieNum以前，所有的图形、MC等等都是处于_level0里的，我们通常使用的_root其实就是_level0。你可以作个测试：trace(_root==_level0)，你会发现返回值是“true"。
那么，我们用loadMovieNum加载 SWF 或 JPEG 文件的时候，程序就要对你指定的_level进行创建，随后再紧接着载入 SWF 或 JPEG 文件。如果像刚才代码中写的那样，不判断_level是否存在而调用其属性，势必无功而反。
解决的方法也很简单，就是用一个循环来判断指定的_level是否存在。一旦_level产生，那么它的种种属性自然可以调用了。代码如下：
loadMovieNum ( “02.swf" , 1 ); //如愿定位
onEnterFrame = function () {
if ( _level1 ) {
with ( _level1 ) {
_x = 50 ;
_y = 100 ;
}
delete onEnterFrame ;
}
};
或者：(上面的代码较好些) loadMovieNum ( “02.swf" , 1 );
function go () {
if ( _level1 ) {
with ( _level1 ) {
_x = 50 ;
_y = 100 ;
}
clearInterval ( fps ); //清除对 setInterval() 的调用
}
}
fps = setInterval ( go,100 );//每隔一定的时间，就调用函数、方法或对象
再或者大家可以使用Macromedia Flash MX 2004中的MovieClipLoader类来判断加载状态。
注意：深度depth值越大，其加载的内容越往后，即越在下层，处于下方，被遮盖；这与级别标识符_levelN 相反，在_levelN 中 N 值越大，其加载的内容越往前，即越在上层，处于上方。
（四）小技巧：用lloadMovieNum()保护你的作品——使用虚假的文件后缀
其实加载外部文件的扩展名不一定非得以 .swf 命名，虽然加载的影片也在IE的临时文件夹中，但已是自定义的文件格式了，这样可以起到保护作用。
例如： loadMovieNum("feng.exe",0);//加载feng.swf 将扩展名改为—> feng.exe加载
/*
loadMovieNum("feng.txt",0); //加载feng.swf 将扩展名改为—> feng.txt 加载
loadMovieNum("feng.doc",0); //加载feng.swf 将扩展名改为—> feng.doc 加载
loadMovieNum("feng.abcde",0); //加载feng.swf将扩展名改为 —> feng.abcde 加载
loadMovieNum("feng",0); //加载feng.swf 将扩展名删除—> feng 加载
*/
【Flash加载外部文件的方法及其技巧】相关文章：